It replaces a part of this Apple Mail export script with a few lines that export some standard headerdata, plus the recipients list and cc-recipients as well, all as part of the same textfile. I replaced the part of of the script between the following lines: if (selection is not {}) then etc. (just after […]

(*
http://veritrope.com
Apple Mail -- Text File Exporter w/ Basic Header Info.
Version 1.0
April 17, 2011

Project Status, Latest Updates, and Comments Collected at:
http://veritrope.com/code/apple-mail-export-to-text-file-w-basic-header-info

Adapted from the original script by Hans Erik Hazelhorst
http://veritrope.com/code/export-apple-mail-messages-and-notes-to-text-files

Installation: Just double-click on the script!

CHANGELOG:
1.00    INITIAL RELEASE
*)


property growlName : "MailTextExport"
property appName : "Mail"
property successCount : "0"

(* CHECK FOR GROWL *)
tell application "System Events"
    set processnames to name of every process
end tell
if appIsRunning("GrowlHelperApp") then
    set isRunning to true
    tell application "GrowlHelperApp"
        set allNotificationsList to {"Success Notification", "Failure Notification"}
        set enabledNotificationsList to {"Success Notification", "Failure Notification"}
        register as application growlName all notifications allNotificationsList default notifications enabledNotificationsList icon of application appName
    end tell
end if

(*MAIN PROGRAM *)

(*TEMP FILES PROCESSED ON THE DESKTOP*)
tell application "Finder"
    if (the folder "Temp Export Folder" exists) then set FolderLoc to (the folder "Temp Export Folder")
    if not (the folder "Temp Export Folder" exists) then
        set FolderLoc to (make new folder at (path to desktop folder) with properties {name:"Temp Export Folder"})
    end if
    set SaveLoc to FolderLoc as string
end tell

(*APPLE MAIL ITEM SELECTION *)
tell application "Mail"
    try
        if (selection is not {}) then
           
            set theMessages to selection
            set msgnr to 1
            repeat with thisMessage in theMessages
                set recipientlist to (to recipients of thisMessage)
               
                (*Adding the Recipients in a separate variable  *)
                set theRecipients to "recipients="
                repeat with CurrentRecipient in recipientlist
                    set theRecipients to theRecipients & return & ¬
                        (address of CurrentRecipient) & "; " & ¬
                        (name of CurrentRecipient) as text
                end repeat
               
                (*...and also the cc-Recipients in a separate variable  *)
                set CcRecipientList to cc recipients of thisMessage
                set theCcRecipients to "cc_recipients="
                repeat with CurrentCCRecipient in CcRecipientList
                    set theCcRecipients to theCcRecipients & return & ¬
                        (address of CurrentCCRecipient) & "; " & ¬
                        (name of CurrentCCRecipient) as text
                end repeat
               
                set myTitle to the subject of thisMessage
                set myContent to the content of thisMessage as text
                set ReplyAddr to the reply to of thisMessage
                set afzender to the sender of thisMessage
                set EmailDate to the date received of thisMessage
                set theSource to the source of thisMessage
               
                (*Custom header with some standard data  *)
                set CustomHeader to "titel=" & myTitle & return & "ReplyTo=" & ReplyAddr & return & ¬
                    "Date=" & EmailDate & return & "Sender=" & afzender & return & "----------"
               
                (*CLEAN TITLE FOR FILE *)
                set previousDelimiter to AppleScript's text item delimiters
                set potentialName to myTitle
                set legalName to {}
                set illegalCharacters to {".", ",", "/", ":", "[", "]"}
                repeat with thisCharacter in the characters of potentialName
                    set thisCharacter to thisCharacter as text
                    if thisCharacter is not in illegalCharacters then
                        set the end of legalName to thisCharacter
                    end if
                end repeat
               
                set AppleScript's text item delimiters to ""
               
                if length of legalName is greater than 32 then
                    set legalName to items 1 thru 32 of legalName as text
                else
                    set legalName to legalName as text
                end if
               
                set AppleScript's text item delimiters to previousDelimiter
                set theFileName to legalName
               
                (*EXPORT TO TXT FILE *)
                set theText to myContent
                set theFilePath to (SaveLoc & msgnr & "_" & theFileName & ".txt")
                set msgnr to msgnr + 1
                set theFileReference to open for access theFilePath with write permission
                write (CustomHeader & return & theRecipients & return & "----------" & return & theCcRecipients & return & "----------" & return & theText) to theFileReference as «class utf8»
                close access theFileReference
                set successCount to successCount + 1
            end repeat
           
            (* GROWL *)
           
            if "GrowlHelperApp" is in processnames then
                tell application "GrowlHelperApp" -- GROWL SUCCESS
                    notify with name ¬
                        "Success Notification" title ¬
                        "Export Success" description "Successfully Exported " & successCount & ¬
                        " Messages to Export Folder!" application name growlName
                end tell
                set successCount to 0
            end if
        else if "GrowlHelperApp" is in processnames then
            tell application "GrowlHelperApp" -- GROWL FAILURE FOR NO SELECTION
                notify with name ¬
                    "Failure Notification" title ¬
                    "Export Failure" description ¬
                    "No Messages or Notes Selected!" application name growlName
            end tell
        else if "GrowlHelperApp" is not in processnames then -- NON-GROWL ERROR MSG. FOR NO SELECTION
            display dialog "No Messages or Notes Selected!" with icon 0
        end if
        (* ERROR HANDLING *)
    on error errText number errNum
        if "GrowlHelperApp" is in processnames then
            tell application "GrowlHelperApp" -- GROWL FAILURE FOR ERROR
                notify with name ¬
                    "Failure Notification" title ¬
                    "Import Failure" description "Failed to export " & return & myTitle & ¬
                    "\"  due to the following error: " & return & errText ¬
                    application name growlName
            end tell
        else if "GrowlHelperApp" is not in processnames then -- NON-GROWL ERROR MSG. FOR ERROR
            display dialog "Item Failed to Export: " & errNum & return & errText with icon 0
        end if
       
    end try
end tell


(* SUBROUTINES *)

on appIsRunning(appName)
    tell application "System Events" to (name of processes) contains appName
end appIsRunning

--REPLACE SUBROUTINE
on replaceString(theString, theOriginalString, theNewString)
    set {od, AppleScript's text item delimiters} to {AppleScript's text item delimiters, theOriginalString}
    set theStringParts to text items of theString
    if (count of theStringParts) is greater than 1 then
        set theString to text item 1 of theStringParts as string
        repeat with eachPart in items 2 thru -1 of theStringParts
            set theString to theString & theNewString & eachPart as string
        end repeat
    end if
    set AppleScript's text item delimiters to od
    return theString
end replaceString

This script exports a rich text copy of selected Evernote items and saves them in RTFD format. It also leaves an HTML copy of the note (and its resources) inside a sub-folder named after the note (in case you find it useful!) Just highlight the notes you want to export in Evernote and then run […]

(*
http://veritrope.com
Export Selected Evernote Items as RTFD Files
Version 1.4
June 11, 2011

Project Status, Latest Updates, and Comments Collected at:
http://veritrope.com/code/export-selected-evernote-items-as-rtfd-files/
Installation: Just run the script!

FastScripts Installation (Optional, but recommended):
--Download and Install FastScripts from http://www.red-sweater.com/fastscripts/index.html
--Copy script or an Alias to ~/Library/Scripts/Applications/Evernote
--Set up your keyboard shortcut

CHANGELOG:
1.40     UPDATED TO MAKE RTF CREATION DATE MATCH EVERNOTE ITEM
1.30    UPDATED TO UTILIZE NEW EVERNOTE APPLESCRIPT SELECTION AVAILABILITY
1.20    UPDATED TO FIX A COSMETIC ISSUE, CHANGE PATH FOR RTFD FILES
1.10     UPDATED TO USE NATIVE HTML EXPORT, CREATE RTFD FILES
1.00    INITIAL RELEASE
*)


property clean_text : ""
property CleanTitle : ""
property theNum : "0"
property RTFPath : ""


(* CHECK FOR GROWL *)
tell application "System Events"
    set processnames to name of every process
end tell

if "GrowlHelperApp" is in processnames then
    tell application "GrowlHelperApp"
        set the allNotificationsList to {"Success Notification", "Failure Notification"}
        set the enabledNotificationsList to {"Success Notification", "Failure Notification"}
        register as application ¬
            "Evernote to RTFD" all notifications allNotificationsList ¬
            default notifications enabledNotificationsList ¬
            icon of application "Evernote"
    end tell
end if

(*MAIN PROGRAM *)

tell application "Evernote"
    try
        (*PICK THE NOTES FROM THE LIST *)
        set SelNotes to the selection
       
        if (SelNotes is not false) then
            (*PICK EXPORT DESTINATION*)
            set SaveLoc to choose folder with prompt "Choose The Destination Folder or Volume:" default location (path to desktop folder)
           
            (*DO THE CONVERSION*)
            my ENEXExport(SelNotes, SaveLoc)
           
            if "GrowlHelperApp" is in processnames then -- GROWL SUCCESS
                tell application "GrowlHelperApp"
                    notify with name ¬
                        "Success Notification" title ¬
                        "Successful Export to RTF!" description ¬
                        "Number of Notes Exported: " & theNum application name "Evernote to RTFD"
                end tell
            end if
        else
            if "GrowlHelperApp" is in processnames then
                tell application "GrowlHelperApp" -- GROWL FAILURE FOR NO SELECTION
                    notify with name ¬
                        "Failure Notification" title ¬
                        "Export Failure" description ¬
                        "No notes selected!" application name "Evernote to RTFD"
                end tell
            else if "GrowlHelperApp" is not in processnames then -- NON-GROWL ERROR MSG. FOR NO SELECTION
                display dialog "No headline or tab selected!" with icon 0
            end if
        end if
       
       
        (* ERROR HANDLING *)
    on error errText number errNum
        if "GrowlHelperApp" is in processnames then
            tell application "GrowlHelperApp" -- GROWL FAILURE FOR ERROR
                notify with name ¬
                    "Failure Notification" title ¬
                    "Import Failure" description "Export Failed due to the following error:  " & errText & return & return & "Note Name: " & CleanTitle ¬
                    application name "Evernote to RTFD"
            end tell
        else if "GrowlHelperApp" is not in processnames then -- NON-GROWL ERROR MSG. FOR ERROR
            display dialog "Item Failed to Import: " & errNum & return & errText with icon 0
        end if
    end try
end tell



(* SUBROUTINES *)
on ENEXExport(SelNotes, SaveLoc)
    (*FIND FOLDER FOR NOTE*)
    tell application "Evernote"
        set theNum to 0
        repeat with SelNote in SelNotes
            set noteToExport to (contents of SelNote)
            set NoteID to (local id of item 1 of noteToExport)
            set noteName to (title of item 1 of noteToExport)
            set EVnotebook to (name of notebook) of item 1 of noteToExport
           
            set noteCreation to (creation date of item 1 of noteToExport)
           
            (*PREPARE HTML FOLDER *)
            tell application "Finder"
                set SingQuote to "-e s/'//g"
                set CleanTitle to do shell script ("echo " & quoted form of noteName & "  | sed -e 's/:/ /g' -e 's/\"//g' -e 's/—/ /g' " & (quoted form of SingQuote)) --CLEAN OUT COLONS FOR FILE PATH (SOUNDS GROSSER THAN IT IS)
                set ArchiveInput to ((SaveLoc as Unicode text) & CleanTitle)
               
                (*NEW HTML EXPORT *)
                tell application "Evernote"
                    export {noteToExport} ¬
                        to ArchiveInput ¬
                        format HTML
                end tell
               
                tell application "Finder"
                    (*LOOK FOR RESOURCE FOLDER *)
                    try
                        set EVNote to (every file of folder ArchiveInput whose ¬
                            name extension is "html")
                        set name of (item 1 of EVNote) to (CleanTitle & ".html")
                    end try
                end tell
               
                (*PREPARE FILENAME *)
                set InputFile to ("" & SaveLoc & CleanTitle & ":" & CleanTitle & ".html") as string
                set ImportPOSIX to (quoted form of (POSIX path of InputFile))
                set SaveRTFLocation to ("" & SaveLoc & CleanTitle & ".rtfd") as string
                set RTFPath to (quoted form of (POSIX path of SaveRTFLocation))
               
                (*CONVERT THE FILE*)
                set clean_text to do shell script ("textutil  -convert rtfd -output " & RTFPath & " " & ImportPOSIX & "")
                set fileCreated to my dateUSToUnix(noteCreation)
                do shell script "touch -t " & fileCreated & " " & RTFPath
            end tell
            set theNum to theNum + 1
        end repeat
    end tell
end ENEXExport

--CONVERT CREATION DATE TO UNIX FORMAT
on dateUSToUnix(noteCreation)
    set y to (year of noteCreation)
    set mo to (month of noteCreation) * 1
    if mo < 10 then set mo to "0" & mo
    set d to (day of noteCreation)
    if d < 10 then set d to "0" & d
    set h to (hours of noteCreation)
    if h < 10 then set h to "0" & h
    set m to (minutes of noteCreation)
    if m < 10 then set m to "0" & m
    set s to (seconds of noteCreation)
    if s < 10 then set s to "0" & s
    return (y & mo & d & h & m & "." & s) as string
end dateUSToUnix

Japanese version of the current “Save A List of URLs From Your Evernote Items As A File”.

(*
http://veritrope.com
Evernote URL List Exporter - Japanese
Version 1.0
September 17, 2010
PROJECT PAGE:
http://veritrope.com/tips/save-a-list-of-urls-from-your-evernote-items-as-a-list

=====================================
WITH GREAT THANKS TO SYNKURO FOR THIS TRANSLATION!
=====================================
CHANGELOG:
1.00    INITIAL RELEASE
*)


(*MAIN PROGRAM *)

(*PREPARE A EVERNOTE'S LIST OF NOTEBOOKS *)
tell application "Evernote"
    activate
    set listOfNotebooks to {}
   
    (*GET THE NOTEBOOK LIST *)
    set EVNotebooks to every notebook
    repeat with currentNotebook in EVNotebooks
        set currentNotebookName to (the name of currentNotebook)
        copy currentNotebookName to the end of listOfNotebooks
    end repeat
   
    (*SORT THE LIST *)
    set Folders_sorted to my simple_sort(listOfNotebooks)
   
    (*USER SELECTION FROM NOTEBOOK LIST *)
    set SelNotebook to choose from list of Folders_sorted with title "Evernote のノートブックを選択" with prompt ¬
        "現在の Evernote ノートブック" OK button name "OK"
    set EVnotebook to item 1 of SelNotebook
    set listofNotes to {} (*PREPARE TO GET EVERNOTE'S LIST OF NOTES *)
    set allNotes to every note in notebook EVnotebook
    repeat with currentNote in allNotes
        try
            set currentNoteURL to (the source URL of currentNote)
            if currentNoteURL is not missing value then
                copy currentNoteURL to the end of listofNotes
            end if
        end try
    end repeat
   
    (*SORT THE LIST *)
    set Notes_sorted to my simple_sort(listofNotes)
    try
        set SelNote to ¬
            choose from list of Notes_sorted with title ¬
                "ノートブック:" & SelNotebook & " に含まれる URL のリスト " OK button name "リストを書き出す" cancel button name "ウインドウを閉じる" with empty selection allowed
       
        (*EXPORT LIST OPTION *)
        if (SelNote is not false) then
            tell application "System Events"
                -- convert list to text
                set old_delim to AppleScript's text item delimiters
                set AppleScript's text item delimiters to return
                set Notes_sorted to Notes_sorted as text
                set AppleScript's text item delimiters to old_delim
                set ExportList to "ノートブック:" & EVnotebook & " に含まれる URL のリスト:" & return & (current date) & return & return & Notes_sorted as Unicode text
                set fn to choose file name with prompt "ファイル名を入力してください" default name "URLリスト-ノートブック_" & EVnotebook & ¬
                    ".txt" default location (path to desktop folder)
                set fid to open for access fn with write permission
                write ExportList to fid
                close access fid
            end tell
        else
            set EVnotebook to item 1 of SelNotebook
        end if
    end try
end tell

(* SUBROUTINES *)

--SORT SUBROUTINE
on simple_sort(my_list)
    set the index_list to {}
    set the sorted_list to {}
    repeat (the number of items in my_list) times
        set the low_item to ""
        repeat with i from 1 to (number of items in my_list)
            if i is not in the index_list then
                set this_item to item i of my_list as text
                if the low_item is "" then
                    set the low_item to this_item
                    set the low_item_index to i
                else if this_item comes before the low_item then
                    set the low_item to this_item
                    set the low_item_index to i
                end if
            end if
        end repeat
        set the end of sorted_list to the low_item
        set the end of the index_list to the low_item_index
    end repeat
    return the sorted_list
end simple_sort