This AppleScript saves a list of all the open tabs in your (frontmost) Chrome window to a new outline in OmniOutliner – Perfect for keeping track of webpages to return to later instead of keeping a billion tabs open all the time! Alfred Users I’ve rolled this script into a ready-to-go workflow for you – […]

(*
◸ Veritrope.com
Save Chrome Tabs to OmniOutliner
VERSION 1.0
June 15, 2014

// TERMS OF USE:
This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License.
To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 444 Castro Street, Suite 900, Mountain View, California, 94041, USA.

// LIKE THIS SCRIPT?
If this AppleScript is helpful to you, please show your support here:
http://veritrope.com/support

// SCRIPT INFORMATION AND UPDATE PAGE
http://veritrope.com/code/save-chrome-tabs-to-omnioutliner

// REQUIREMENTS
More details on the script information page.

// CHANGELOG
1.00    INITIAL RELEASE

*)



(*
======================================
// MAIN PROGRAM
======================================
*)


--RESET VALUES
set urlList to {}
set currentTab to 0

--SET DATE STAMP
set the dateStamp to ((the current date) as string)
set noteTitle to "URL List from Chrome Tabs on " & the dateStamp

--MAKE NEW OUTLINE
tell application "OmniOutliner" to set newOut to make new document with properties {name:noteTitle}
set docName to (name of newOut)

--PROCESS TABS OF FRONTMOST CHROME WINDOW
tell application "Google Chrome"
    set successCount to 0
    set ChromeWindow to the front window
    set tabCount to (count of (tabs of ChromeWindow))
   
    --GET TAB INFORMATION  
    try
        repeat with t in (tabs of ChromeWindow)
            set currentTab to currentTab + 1
            set tabTitle to (title of t)
            set tabURL to (URL of t)
           
            --MAKE ROW IN OMNIOUTLINER
            tell application "OmniOutliner"
                tell its document docName
                    set aRow to make new row with properties {topic:tabTitle, note:tabURL}
                    set note expanded of aRow to true
                    expandAll
                end tell
            end tell
           
            --INCREMENT SUCCESS COUNT
            set successCount to (successCount + 1)
        end repeat
    end try
end tell


--NOTIFY RESULTS
my notification_Center(successCount, tabCount)

(*
======================================
// NOTIFICATION SUBROUTINE
======================================
*)


--NOTIFICATION CENTER
on notification_Center(successCount, itemNum)
    set Plural_Test to (successCount) as number
   
    if Plural_Test is -1 then
        display notification "No Tabs Exported!" with title "Send Chrome Tabs to OmniOutliner" subtitle "◸ Veritrope.com"
       
    else if Plural_Test is 0 then
        display notification "No Tabs Exported!" with title "Send Chrome Tabs to OmniOutliner" subtitle "◸ Veritrope.com"
       
    else if Plural_Test is equal to 1 then
        display notification "Successfully Exported " & itemNum & ¬
            " Tab to OmniOutliner" with title "Send Chrome Tabs to OmniOutliner" subtitle "◸ Veritrope.com"
       
    else if Plural_Test is greater than 1 then
        display notification "Successfully Exported " & itemNum & ¬
            " Tabs to OmniOutliner" with title "Send Chrome Tabs to OmniOutliner" subtitle "◸ Veritrope.com"
    end if
   
    set itemNum to "0"
    delay 1
end notification_Center

This AppleScript saves a list of all the open tabs in your (frontmost) Google Chrome window to a new list in Reminders.app – Perfect for keeping track of webpages to return to later instead of keeping a billion tabs open all the time. I think this could be especially nice for people who share lists […]

(*
◸ Veritrope.com
Save Chrome Tabs to Reminders
VERSION  1.0
June 15, 2014

// UPDATE NOTICES
    ** Follow @Veritrope on Twitter, Facebook, Google Plus, and ADN for Update Notices! **

// SUPPORT VERITROPE!
    If this AppleScript was useful to you, please take a second to show your love here:
    http://veritrope.com/support
   
// SCRIPT INFORMATION AND UPDATE PAGE:
    http://veritrope.com/code/save-chrome-tabs-to-reminders

// TERMS OF USE:
    This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License.
    To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 444 Castro Street, Suite 900, Mountain View, California, 94041, USA.

// CHANGELOG:
    1.00    INITIAL RELEASE
   
*)


--RESET VALUES
set currentTab to 0

--SET DATE STAMP
set the dateStamp to ((the current date) as string)

-- PREPARE THE LIST
set url_list to {}
set listName to "URL List from Chrome Tabs on " & the dateStamp

--PROCESSING FRONTMOST CHROME WINDOW
tell application "Google Chrome"
    activate
    set chromeWindow to the front window
    set tabCount to (count of (tabs of chromeWindow))
    set successCount to 0
   
    --MAKE LIST WITH TIMESTAMP
    tell application "Reminders" to set theList to (make new list with properties {name:listName})
   
    --PROCESS TABS 
    repeat with w in chromeWindow
        try
            --GET TAB INFORMATION  
            repeat with t in (tabs of w)
                set TabTitle to (title of t)
                set TabURL to (URL of t)
               
                --MAKE REMINDER
                tell application "Reminders"
                    tell theList
                        make new reminder with properties {name:TabTitle, body:TabURL}
                    end tell
                end tell
               
                --INCREMENT SUCCESS COUNT
                set successCount to (successCount + 1)
               
            end repeat
        end try
    end repeat
end tell

--NOTIFY RESULTS
my notification_Center(successCount, tabCount)

(*
======================================
// NOTIFICATION SUBROUTINE
======================================
*)


--NOTIFICATION CENTER
on notification_Center(successCount, itemNum)
    set Plural_Test to (successCount) as number
   
    if Plural_Test is -1 then
        display notification "No Tabs Exported!" with title "Send Chrome Tabs to Reminders" subtitle "◸ Veritrope.com"
       
    else if Plural_Test is 0 then
        display notification "No Tabs Exported!" with title "Send Chrome Tabs to Reminders" subtitle "◸ Veritrope.com"
       
    else if Plural_Test is equal to 1 then
        display notification "Successfully Exported " & itemNum & ¬
            " Tab to Reminders" with title "Send Chrome Tabs to Reminders" subtitle "◸ Veritrope.com"
       
    else if Plural_Test is greater than 1 then
        display notification "Successfully Exported " & itemNum & ¬
            " Tabs to Reminders" with title "Send Chrome Tabs to Reminders" subtitle "◸ Veritrope.com"
    end if
   
    set itemNum to "0"
    delay 1
end notification_Center

This AppleScript saves a list of all the open tabs in your (frontmost) Chrome window to a new item in DEVONthink Pro – Perfect for keeping track of webpages to return to later instead of keeping a billion tabs open all the time! Alfred Users I’ve rolled this script into a ready-to-go workflow for you […]

(*
◸ Veritrope.com
Save Chrome Tabs to DEVONthink Pro
VERSION 1.0
June 16, 2014
)

// UPDATE NOTICES
     ** Follow @Veritrope on Twitter, Facebook, Google Plus, and ADN for Update Notices! **

// SUPPORT VERITROPE!
     If this AppleScript was useful to you, please take a second to show your love here:
     http://veritrope.com/support

// SCRIPT INFORMATION AND UPDATE PAGE
     http://veritrope.com/code/save-chrome-tabs-to-devonthink-pro

// REQUIREMENTS
     More details on the script information page.

// CHANGELOG
    1.0  INITIAL RELEASE

// TERMS OF USE:
     This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License.
     To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 444 Castro Street, Suite 900, Mountain View, California, 94041, USA.


*)


(*
======================================
// MAIN PROGRAM
======================================
*)


-- PREPARE THE LIST
set url_list to {}
set the date_stamp to ((the current date) as string)
set NoteTitle to "URL List from Chrome Tabs on " & the date_stamp

--PROCESSING FRONTMOST CHROME WINDOW
tell application "Google Chrome"
    activate
    set chromeWindow to the front window
    set tabCount to (count of (tabs of chromeWindow))
    set successCount to 0
   
    --GET TAB INFO
    repeat with w in chromeWindow
        try
            repeat with t in (tabs of w)
                set TabTitle to (title of t)
                set TabURL to (URL of t)
                --set TabInfo to ("" & TabTitle & return & TabURL & return & return)
                set TabInfo to ("<a href=\"" & TabURL & "\">" & TabTitle & "</a><br/>")
                --ADD TO LIST
                copy TabInfo to the end of url_list
               
                --INCREMENT SUCCESS COUNT
                set successCount to (successCount + 1)
            end repeat
        end try
    end repeat
end tell

-- CONVERT URL_LIST TO TEXT
set old_delim to AppleScript's text item delimiters
set AppleScript's text item delimiters to return
set url_list to url_list as text
set AppleScript's text item delimiters to old_delim

--MAKE THE ITEM IN DEVONthink Pro  
tell application "DEVONthink Pro"
   
    create record with {type:html, source:url_list, name:NoteTitle} in current group
end tell

--NOTIFY RESULTS
my notification_Center(successCount, tabCount)

(*
======================================
// NOTIFICATION SUBROUTINE
======================================
*)


--NOTIFICATION CENTER
on notification_Center(successCount, itemNum)
    set Plural_Test to (successCount) as number
   
    if Plural_Test is -1 then
        display notification "No Tabs Exported!" with title "Send Chrome Tabs to DEVONthink Pro" subtitle "◸ Veritrope.com"
       
    else if Plural_Test is 0 then
        display notification "No Tabs Exported!" with title "Send Chrome Tabs to DEVONthink Pro" subtitle "◸ Veritrope.com"
       
    else if Plural_Test is equal to 1 then
        display notification "Successfully Exported " & itemNum & ¬
            " Tab to DEVONthink Pro" with title "Send Chrome Tabs to DEVONthink Pro" subtitle "◸ Veritrope.com"
       
    else if Plural_Test is greater than 1 then
        display notification "Successfully Exported " & itemNum & ¬
            " Tabs to DEVONthink Pro" with title "Send Chrome Tabs to DEVONthink Pro" subtitle "◸ Veritrope.com"
    end if
   
    set itemNum to "0"
    delay 1
end notification_Center