(OLD VERSION) Safari URLs to Evernote!

Description

Want to Save a List of Your Safari Tabs into Evernote? This AppleScript will export a list of your open tabs as a simple text file:
  • This AppleScript creates a note with a list of the URLs of each open tab in the frontmost window of Safari.
  • Efficiency was foremost in my mind when creating this script. As such, the script creates the note in the default notebook and without any tagging. If anyone thinks that notebook selection and tagging should be included, please let me know in the comments below and I'll consider adding it in!

The Code

(*
Veritrope.com
Safari Tab List to Evernote
VERSION 1.1
March 10, 2013

// TERMS OF USE:
This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License.
To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 444 Castro Street, Suite 900, Mountain View, California, 94041, USA.

// LIKE THIS SCRIPT?
If this AppleScript is helpful to you, please show your support here:
http://veritrope.com/support

// SCRIPT INFORMATION AND UPDATE PAGE
http://veritrope.com/code/export-all-safari-tabs-to-evernote

// REQUIREMENTS
More details on the script information page.

// CHANGELOG
1.1  REORGANIZED SCRIPT FORMAT, ADDED CODE COMMENTS
1.0  INITIAL RELEASE


*)



(*
======================================
// MAIN PROGRAM
======================================
*)

-- RESET URL LIST
set url_list to {}

-- GET TODAY'S DATE
set the date_stamp to ((the current date) as string)

-- SET THE NOTE TITLE
set NoteTitle to "URL List from Safari Tabs on " & the date_stamp

-- GET TABS FROM SAFARI
tell application "Safari"
    activate
    set safariWindow to window 1
    repeat with w in safariWindow
        try
            repeat with t in (tabs of w)
                set TabTitle to (name of t)
                set TabURL to (URL of t)
                set TabInfo to ("" & TabTitle & return & TabURL & return & return)
                copy TabInfo to the end of url_list
            end repeat
        end try
    end repeat
end tell

-- CONVERT LIST TO TEXT
set old_delim to AppleScript's text item delimiters
set AppleScript's text item delimiters to return
set url_list to url_list as text
set AppleScript's text item delimiters to old_delim

-- MAKE THE NOTE IN EVERNOTE
tell application "Evernote"
    set EVNote to (create note with text url_list title NoteTitle)
end tell