(*
Veritrope.com
Write Today's Completed Tasks In OmniFocus to a Text File
Version 1.0
April 30, 2011

Project Status, Latest Updates, and Comments Collected at:
http://veritrope.com/code/write-todays-completed-tasks-in-omnifocus-to-a-text-file

// SCRIPT BASED UPON ROBTREW'S HANDLER
--ORIGINALLY POSTED ON THE OMNIFOCUS FORUM:
http://forums.omnigroup.com/showthread.php?t=13849


// RECOMMENDED INSTALLATION INSTRUCTIONS:

FastScripts Installation (Optional, but recommended):
--Download and Install FastScripts from http://www.red-sweater.com/fastscripts/index.html
--Copy script or an Alias to ~/Library/Scripts/Applications/OmniFocus
--Set up your keyboard shortcut
*)


(*
======================================
// MAIN PROGRAM
======================================
*)

--GET TODAY'S DATE
set dteToday to date (short date string of (current date))

--CHOOSE FILE NAME / SAVE LOCATION
set theFilePath to choose file name default name "Today_Task.txt"

--GET OMNIFOCUS INFORMATION
set today_Tasks to my do_OmniFocus()

--WRITE THE TEXT FILE
my write_File(theFilePath, today_Tasks)

(*
======================================
// MAIN HANDLER SUBROUTINES
======================================
*)

--GET OMNIFOCUS INFORMATION
on do_OmniFocus()
    set dteToday to date (short date string of (current date))
    tell application id "com.omnigroup.OmniFocus"
        tell default document
            set refDoneToday to a reference to (flattened tasks where (completion date ≥ dteToday))
            set {lstName, lstContext, lstProject} to {name, name of its context, name of its containing project} of refDoneToday
            set strText to ""
            repeat with iTask from 1 to count of lstName
                set {strName, varContext, varProject} to {item iTask of lstName, item iTask of lstContext, item iTask of lstProject}
                set strText to strText & "OmniFocus: " & tab & strName
                if varContext is not missing value then set strText to strText & " @" & varContext
                if varProject is not missing value then set strText to strText & " (" & varProject & ")"
                set strText to strText & return
            end repeat
        end tell
    end tell
    strText
end do_OmniFocus


(*
======================================
// UTILITY SUBROUTINES
======================================
*)

--EXPORT TO TXT FILE
on write_File(theFilePath, today_Tasks)
    set theText to today_Tasks
    set theFileReference to open for access theFilePath with write permission
    write theText to theFileReference as «class utf8»
    close access theFileReference
end write_File